Provenance SPARQLer

A platform for clarifying and commenting on SPARQL queries at the new Getty Provenance endpoint. This site is not affiliated with the Getty Research Institute.

Artists Involved in Provenance Events (0006)

Query #: 006
Created:
Topic: auction-events
Difficulty: intermediate

This query returns auction events and the artists involved in them.

activities artists under construction

This query returns auction events and the artists involved in them. By including URIs for particular artists, you can use it to filter for only those artists.

Introduction #

In 0001, users were shown how to proceed from events to artists (among other things). In theory, one could reverse this query to do the opposite. But this is not the recommended path, especially if we do not wish to reconstruct the results of particular auction_events. This is a simple query, moving from artist to sale_activity (and sale_sub_activity, as the user will see).

NB: The query must be limited in certain ways in order to avoid timing out at the SPARQL endpoint. There are simply too many possible artists to run through, with too many associated sale_activities. The query must either be limited using the LIMIT operator, as below, or by drilling down on particular artists (see commentary).

The relationship between artist, artwork, sale_activity, and sale_sub_activity is as follows.

(Diagram coming soon)

Query #

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX la: <https://linked.art/ns/terms/>
PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?artist_label ?artwork_name ?sale_activity_label ?sale_activity ?sale_sub_activity_label WHERE {
#  ?artist skos:exactMatch <http://vocab.getty.edu/ulan/500400787> .
  ?production_sub_event crm:P14_carried_out_by ?artist .
#  ?production_sub_event crm:P14_carried_out_by <https://data.getty.edu/provenance/8dd16496-278f-3bd3-8b1b-15e41195de61> .
  ?production_event crm:P9_consists_of ?production_sub_event .
  ?artwork crm:P108i_was_produced_by ?production_event .
  ?artwork crm:P1_is_identified_by ?artwork_identifier .
  ?artwork_identifier crm:P2_has_type <http://vocab.getty.edu/aat/300404670> .
  ?artwork_identifier crm:P190_has_symbolic_content ?artwork_name .
  ?sale_sub_activity crm:P24_transferred_title_of|crm:P30_transferred_custody_of ?artwork .
  ?sale_activity crm:P9_consists_of ?sale_sub_activity .
  ?artist rdfs:label ?artist_label .
  ?sale_activity rdfs:label ?sale_activity_label .
  ?sale_sub_activity rdfs:label ?sale_sub_activity_label .
  ?artwork rdfs:label ?artwork_label .
} 
LIMIT 100

Commentary #

Notes #